Xendo's Warlock Macros

From EFWiki

Path: Classes | Warlock

Contents 1 Multi-Minion 2 Control Minion 3 Dismiss Minion 4 Soulwell 5 Store Soul 6 Short Buffs 7 Dispel 8 Fear with focus 9 Seduction with focus 10 Banish with focus 11 Enslave Demon with focus 12 Swap Target and Focus

Multi-Minion

• Summons Imp
• [Ctrl] Summons Voidwalker
• [Shift] Summons Succubus
• [Alt] Summons Felhunter
• Uses Fel Concentration if available.

#showtooltip [mod:ctrl]Summon Voidwalker;[mod:shift]Summon Succubus;[mod:alt]Summon Felhunter;Summon Imp
/cast Fel Domination
/cast [mod:ctrl]Summon Voidwalker;[mod:shift]Summon Succubus;[mod:alt]Summon Felhunter;Summon Imp

Control Minion

• Orders pet to attack or return with a single button.
• Auto-buffs voidwalker with Consume Shadows before sending it into combat.

/petfollow [target=pettarget,exists,pet]
/stopmacro [noexists][dead]
/cast [pet:Voidwalker,nocombat,target=pettarget,noexists]Consume Shadows
/petattack [target=pettarget,noexists]

Dismiss Minion

• Dismiss whatever pet you have out.

/run PetDismiss()

Soulwell

• Erects a soulwell when in a group and not in combat.
• Creates a healthstone otherwise.

#showtooltip
/cast [mod:ctrl]Create Healthstone;[combat]Create Healthstone;[group]Ritual of Souls;Create Healthstone
/stopmacro [mod:ctrl][combat][nogroup]
/me starts performing the Ritual of Souls...

Store Soul

• Puts a soulstone on a friendly target (defaults to self).
• Announces in /p or /ra as appropriate.

#showtooltip
/use [help]Master Soulstone;[target=player]Master Soulstone
/stopmacro [nogroup][dead][nohelp][noexists]
/run local C;if GetNumRaidMembers()>0 then C="RAID"else C="PARTY"end SendChatMessage(">> Storing %t's soul. <<",C)

Short Buffs

• Casts Detect Invisibility on a mouseover-target, a friend, or self.
• [Ctrl] Casts Unending Breath on a mouseover-target, a friend, or self.

#showtooltip
/cast [target=mouseover,help,mod:ctrl][help,mod:ctrl][help,btn:2][target=player,mod:ctrl][target=player,btn:2]Unending Breath; [target=mouseover,help][help][target=player][]Detect Invisibility

Dispel

• Dispels harmful magic from a friend or self, using Devour Magic or by using a Spellstone (whichever is available).
• If neither are available a Felhunter will be summoned, or a Spellstone created when holding [Ctrl].

#showtooltip
/cast [pet:Felhunter,target=mouseover,help]Devour Magic;[pet:Felhunter,help]Devour Magic;[pet:Felhunter,target=player]Devour Magic;[equipped:Relic]Master Spellstone;[mod:ctrl]Create Spellstone;Summon Felhunter

Fear with focus

• Fears a hostile target and puts it in focus for subsequent fears.
• Right mouse button casts Curse of the Elements, to prevent early breaks.

#showtooltip Fear
/focus [target=focus,exists,nodead]focus;[]
/cast [target=focus,btn:2]Curse of the Elements;[target=focus]Fear

Seduction with focus

• Seduces a hostile target and puts it in focus for subsequent seduction.
• Automatically applies Curse of the Elements on the first cast of Seduction.
• Can re-apply Seduction before duration is fully over.
• Summons (a new) Succubus if one is not out already.

#showtooltip [pet:Succubus]Seduction;Summon Succubus
/cast [nopet:Succubus]Summon Succubus;[target=focus,exists,nodead];Curse of the Elements
/stopmacro [nopet:Succubus]
/focus [target=focus,exists,nodead]focus;[]
/petfollow
/cast [target=focus]Seduction

Banish with focus

• Banishes a hostile target and puts it in focus for subsequent banishment.
• Right mouse button to cast Rank 1 (short duration).

#showtooltip Banish
/focus [target=focus,exists,nodead]focus;[]
/cast [target=focus,btn:2]Banish(Rank 1);[target=focus]Banish

Enslave Demon with focus

• Enslaves a demon and puts it in focus for subsequent enslavement.

#showtooltip Enslave Demon
/focus [target=focus,exists,nodead]focus;[]
/cast [target=focus]Enslave Demon

Swap Target and Focus

• Put target in focus, and focus in target.

/tar focus
/stopmacro [noexists]
/cleartarget [target=focus,noexists]
/targetlasttarget
/focus
/targetlasttarget